Moonmile Solutions Blog

落とし穴、と言いますか、やっぱり ComboBox コントロールの落とし穴っぽい動きの話です。

■問題

単純にフォームに ComboBox コントロールを貼り付けて、項目を選択した直後のイベントを拾いたい。
さてどうするのか？

という要件があって、なんか手元のコードでは、SelectedIndexChanged イベントを拾っていた訳です。
SelectedIndexChanged イベントでも悪くはないのですが、ComboBox で項目を選択している途中のイベントも拾ってしまうので、【最後のイベントだけを拾う】ってのがなかなかでき難い、というか、これでバグっているので。

■イベントは4種類ある

あらためて ComboBox のイベントを見ると、それらしいものが4つほどあります。

・SelectedIndexChanged イベント：選択項目が変更されるたびに発生する
・SelectionChangeCommitted イベント：項目がコミットするタイミングで発生する
・DropDownClosed イベント：ドロップダウンのリストが、閉じられるタイミングで発生する
・TextChanged イベント：ComboBox のテキストが変更されるタイミングで発生する

■試行錯誤してみる

↓なコードを書いて、発生するイベントを見てみます。

Private Sub ComboBox1_SelectedIndexChanged(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles ComboBox1.SelectedIndexChanged
    Debug.Print("ComboBox1_SelectedIndexChanged")
End Sub

Private Sub ComboBox1_SelectionChangeCommitted(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles ComboBox1.SelectionChangeCommitted
    Debug.Print("ComboBox1_SelectionChangeCommitted")
End Sub

Private Sub ComboBox1_DropDownClosed(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles ComboBox1.DropDownClosed
    Debug.Print("ComboBox1_DropDownClosed")
End Sub

Private Sub ComboBox1_TextChanged(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles ComboBox1.TextChanged
    Debug.Print("ComboBox1_TextChanged")
End Sub

動かし方は、

・マウスで選択する。
・マウスでスクロールバーを動かす。
・キーボードでリストを選択する。
・リストを閉じたままで、キーボードで動かす。

のパターンがあります。

一見すると、SelectedIndexChanged イベントで良いような気もするのですが、リストを選択している途中もバシバシとイベントが発生するので駄目です。
マウスで動かしているときは発生しないのですが、キーボードの矢印キーで動かすと連続して発生します。

じゃあ、SelectionChangeCommitted でもいいのかな、と思っていると。
リストを閉じる時に、右にある▼をクリックすると、SelectionChangeCommitted イベントが発生しないという落とし穴…なんじゃそりゃ？状態なので、ちょっと使えません。

そうなると、DropDownClosed イベントでリストが閉じられるタイミングを拾えばよいのでは？と思うのですが、
きちんと▼を押して、リストから選択するときは良いのですが、リストを出さずに上下のカーソルキーで直接動かすときには、実は DropDownClosed イベントが発生しないのです。えぇ SelectionChangeCommitted イベントは発生するんですけどね。

そんな訳で、素直に TextChanged イベントを使うのが無難ですね…という結論でした。

ただ、TextChanged イベントの場合は、編集可能な ComboBox のときにはイベントがややこしいんですよね…悩ましい、という話

ちょっとアリスシリーズ風に書き下し。
要は、デバッグ用に呼び出し元のクラス名を取得したいのですが、デバッグ用なので new 時にインスタンスやクラス名を渡したくない、のですね。なので、呼び出されたクラス/メソッドのほうから、こっそりと StackFrame を使って、呼び出し元のクラス名を取得するという技です。

' 参考
' 自分自身のクラス名とメソッド名:Gushwell's C# Dev Notes
' http://gushwell.ldblog.jp/archives/50715142.html

Public Class Form1

	''' <summary>
	''' アリスを作成
	''' </summary>
	''' <param name="sender"></param>
	''' <param name="e"></param>
	''' <remarks></remarks>
	Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click

		Dim alice As New Alice
		alice.Check()

	End Sub

	''' <summary>
	''' ロリータを作成
	''' </summary>
	''' <param name="sender"></param>
	''' <param name="e"></param>
	''' <remarks></remarks>
	Private Sub Button2_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button2.Click

		Dim lolita As New Lolita
		lolita.Check()

	End Sub
End Class

Public Class Person

	Protected _bag As Bag

	''' <summary>
	''' コンストラクタ
	''' </summary>
	''' <remarks></remarks>
	Public Sub New()
		' バッグを作成（作成者名はバッグの内部で保存される）
		_bag = New Bag
	End Sub
	''' <summary>
	''' 作成者を表示
	''' </summary>
	''' <remarks></remarks>
	Public Sub Check()
		MessageBox.Show("class in " + _bag.GetClassName)
	End Sub

End Class

''' <summary>
''' アリスクラス
''' </summary>
''' <remarks></remarks>
Public Class Alice
	Inherits Person
End Class

''' <summary>
''' ロリータクラス
''' </summary>
''' <remarks></remarks>
Public Class Lolita
	Inherits Person
	' ※本来は、クラス名を渡すべき
	Public Sub New()
		_bag = New Bag("LOLITA")
	End Sub

End Class

Public Class Bag

	Protected _cname As String

	''' <summary>
	''' コンストラクタ
	''' </summary>
	''' <remarks></remarks>
	Public Sub New()

		Dim st As New StackTrace(False)
		' Bag -> Person -> Alice の順で 2 を指定する
		Dim sf As StackFrame = st.GetFrame(2)
		' 呼出元を保存しておく
		_cname = sf.GetMethod.ReflectedType.FullName

	End Sub

	''' <summary>
	''' 本来はクラス名を渡すべき
	''' </summary>
	''' <param name="cname"></param>
	''' <remarks></remarks>
	Public Sub New(ByVal cname As String)
		_cname = cname
	End Sub

	''' <summary>
	''' 設定されているクラス名を取得
	''' </summary>
	''' <returns></returns>
	''' <remarks></remarks>
	Public Function GetClassName() As String
		Return _cname
	End Function
End Class

Alice クラス内で、new Bag をしています。この Bag を生成したのは誰か？というのは、本来ならば Alice のインスタンスか、クラス名を渡す、あるいは、Bag プロパティに設定する、ということをやる必要があるのですが、これをスタックフレームを使って呼び出し元のクラス名を取得するようにします。

Bag クラスのコンストラクタの部分が少しトリッキーなことになっています。

	Public Sub New()

		Dim st As New StackTrace(False)
		' Bag -> Person -> Alice の順で 2 を指定する
		Dim sf As StackFrame = st.GetFrame(2)
		' 呼出元を保存しておく
		_cname = sf.GetMethod.ReflectedType.FullName

	End Sub

StackTrace クラスでスタックトレースを取得した後、GetFrame メソッドで呼び出し元を取得します。このときに、スタックの状態が、Bag -> Person -> Alice になっているので「2」を指定しています。
間に Person クラスが挟まるのは、Alice クラスとの継承関係があるからです。なので、フォームからの呼び出しをチェックする場合も、Form クラスを継承していることを考慮にいれて、GetFrame メソッドに渡す値を調節しないといけません。ややこしいですね…というか、実装依存になるので、ピンポイントでしか使えない技です。なので、素直にクラス名を渡したほうがよさそうです。

こういう場合、XmlDocument クラスのようにファクトリーパターンを使います。コンストラクタにクラス名を渡すよりは自然かも。

Dim bag = Bag.CreateInstanceWithName("Lolita")
'あるいは
Dim bag As New Bag("Lolita")

■参考

自分自身のクラス名とメソッド名:Gushwell’s C# Dev Notes
http://gushwell.ldblog.jp/archives/50715142.html

Assembly.LoadFrom を使って別のアセンブリにあるフォームを起動する | Moonmile Solutions Blog
http://www.moonmile.net/blog/archives/2312

上記なところで、Assembly.LoadFrom メソッドを使うと動的にアセンブリをロードすることができる、って話をしましたが、実はプラグインでなければ【動的】である必要はないわけで、あらかじめ【参照設定】などでアセンブリを指定しておく方法もあります。

つまりは、

Dim cname as string = "クラス名"
Dim t as Type = Type.GetType( cname )
Dim f as Form = System.Activator.CreateInstance(t)

な感じで、Type から直接作ればよいわけです。

実は前回、なんでわざわざ動的ロードにしたのかなぁ、と思っていたら、この cname が参照設定先の別のアセンブリにあると、単純にクラス名（例えば、FormSub とか）だけではオブジェクトを作成できなかったからなのです。

アセンブリの構成が、

SampleMain.exe
+ FormMain

のように単一のアセンブリに入っていれば、そのまま Type.GetType(“FormMain”) でロードができるのですが、

SampleMain.exe
+ FormMain
SampleSub.exe
+ FormSub

のように、Main.exe から Sub.exe を【参照設定】している場合は、Main.exe の中では、Type.GetType(“FormSub”) ができません。
別アセンブリの場合は、【修飾名】が必要って訳です。

で、この修飾名はどうやって取り出すかというと、AssemblyQualifiedName で取り出します。

Type.GetType メソッド (String) (System)
http://msdn.microsoft.com/ja-jp/library/w3f99sx1(v=VS.80).aspx
Type.AssemblyQualifiedName プロパティ (System)
http://msdn.microsoft.com/ja-jp/library/system.type.assemblyqualifiedname(v=VS.80).aspx

なにやら、ややこしいことが書いてありますが、要は試しのプログラムを作って AssemblyQualifiedName プロパティで取り出してみればば良いわけです。下記のように試してみます。

Dim frm as new FormSub
Debug.Print( frm.GetType.AssemblyQualifiedName )

すると、「FormSub, SampleSub, Version=1.0.0.0, Culture=neutral, PublicKeyToken=null」のように修飾名が取れるので、そのままクラス名として利用します。

Dim cname as string = "FormSub, SampleSub, Version=1.0.0.0, Culture=neutral, PublicKeyToken=null"
Dim t as Type = Type.GetType( cname )
Dim f as Form = System.Activator.CreateInstance(t)

ロードする対象のクラスを切り替えたいとき（画面を切り替えたいとき）は、クラス名の「FormSub」を変えれば ok ですね。